Bevel Cut Out George Script

(A George Script For Aura)

Written By J.L. White

Notice the logo above with the cut out oval? That's what this tutorial is about. It shows you how to do this in Aura. There are a number of steps you need to follow and we have included a George script to take care of most of it for you.

I had seen this done all over the web and saw a number of PhotoShop tutorials showing how. Well since I don't care much for PhotoShop, I decided to try and figure a way to do this in Aura. Below is the method I used.

First start with a clean project loaded. Next load the image as a brush that you plan on using for the background on your web page, or you can use a solid color if you wish. Select the "Wrapping" Filter from the filters menu. Hit reset and make sure the "Fill Image" option is selected. You may want to turn Anti Aliasing OFF on the Main panel as this sometimes "Smooths" the picture out too much. Try it both ways to see which looks best. Then go ahead and run the filter. If you are going to just use a solid color, select it and do a fill of the image with that color.

Now load the image or logo as a brush, that you want to have inside the oval shape. Stamp it down on the background. Next duplicate the Layer and then make sure to reselect the "Top" layer. Select the "Oval" tool and make an oval around the logo with your right button. Yes with your right button. We want to cut this part of the image out. Once you do this you will not see any difference, this is because you have a duplicate of the original showing through the hole. You can change the display to "Current" if you want to make sure.

Once you have the hole cut, you can bring up the "Shadow" Filter and apply it to the "same" layer, not a "New" layer. Next run the included BevelCutOut George script. This will take the top image and remove the border and add a beveled edge and blur to the oval shape. You can now pick up the oval as a brush with the "Right" button again and reposition it over your logo below, but only if you need to. Next hit "Merge Display" and you will have the above look that you can cut out as a brush and use on your Web site.

You can go to the bottom of the page from here and click on the link to download this script, or follow along now as we break down the script, to show you how it does what it does. The acutal script is between the start and end George script lines. My comments will look like this < --- Comment Goes Here --- > and are not actually part of the script itself.

< ---------------------------------- Start of George Script ----------------------- >
// Cut Out Bevel Edge
// By J.L. White
// (C)2000 Visual Inspirations Inc.
< --- The first 4 lines are just comment lines. Anything that starts with // is a comment --- >

Param none
connect Aura Commands
< --- Tells Aura what options to use, like rectangle, circle, for this we need none --- >

tv_GetWidth
parse result MyWidth
< --- Gets Image Width --- >

tv_GetHeight
parse result MyHeight
< --- Gets Image Height --- >

tv_ReqNum 2 1 MyWidth "Select Bevel Width?"
parse result OffNum
< --- Asks user for bevel width --- >

tv_ReqNum 50 1 100 "Select Bevel Opacity?"
parse result PowerNum
< --- Asks for bevel opacity --- >

tv_ReqNum 2 0 20 "Amount To Apply For Gaussian Blur?"
parse result BlurNum
< --- Asks for amount of blur to use --- >

tv_GetAPen
parse result ra ga ba aa
< --- Gets Current Foreground color settings --- >

tv_BrushPower 100
< --- Sets brush to full opacity --- >

tv_SpareKill
tv_SpareCopy
tv_SpareSwap
< --- Kills spare, copies main, and then swaps to spare --- >

tv_SetAPen 0 0 0
< --- Sets Foreground color to black --- >

tv_BrushCut 0 0 MyWidth MyHeight 1
tv_Handle 0 0
tv_SetDrawMode "STAMP"
tv_Dot 0 0
< --- Cuts out image and stamps it back down as all black--- >

tv_Filter ColorOp.dll 0 0 MyWidth MyHeight "r g b 255-a"
< --- Inverts the Alpha channel --- >

tv_BrushCut 0 0 MyWidth MyHeight 1
tv_SpareSwap
tv_SetDrawMode "STAMP"
tv_BrushPower PowerNum
tv_Handle 0 0
tv_Dot -OffNum -OffNum
< --- Cuts the image, flips back to main and stamps down offset by bevel num --- >

tv_SetAPen 255 255 255
tv_Dot OffNum OffNum
< --- Stamps image down with white color offset in opposite direction --- >

tv_SetDrawMode "ERASE"
tv_Dot 0 0
< --- Stamps down and erases everything in the middle of the oval --- >

tv_SetDrawMode "Color"
for i = 1 to OffNum
tv_BrushOutline
end
< --- Adds a border to the brush --- >

tv_BrushPower 100
< --- Reset brush opacity to 100 --- >

tv_SpareSwap
tv_SetDrawMode "STAMP"
tv_BrushPower 100
tv_Handle 0 0
tv_Dot -OffNum -OffNum
< --- Swap to spare and stamp image down offset by bevel num --- >

tv_Filter ColorOp.dll 0 0 MyWidth MyHeight "r g b 255-a"
< --- Reverses Alpha channel again --- >

tv_BrushCut 0 0 MyWidth MyHeight
tv_SpareSwap
tv_Handle 0 0
tv_SetDrawMode "ERASE"
tv_Dot 0 0
< --- Picks up brush, swaps back and erases the other parts based on bevel num--- >

tv_SetDrawMode "Color"
if BlurNum > 0
tv_GBlur BlurNum
end
< --- Blurs image based on user settings --- >

tv_SetAPen ra ga ba
< --- Resets Foreground color --- >

exit
< --- Exits script --- >

< ---------------------------------- End of George Script ----------------------- >

Click Here to Download BevelCut.zip

Well that does it for this one, till next time...

To contact Jeff White you can E-Mail him at jeff@vionline.com