Colorize Image George Script

Written By J.L. White

One thing I had never really cared about in Aura, is its "Colorize" routine. While it works, the colors are usually too harsh (bright and washed out) for me. I ran across a message from Paul Pichette on a method he found to work much better. I tried it and yes in deed it worked Fabulously! What it would do is adjust the Alpha channel to various levels and that would let the next layer show through. This comes in very handy, as it can be anything from a solid color, to a range of colors, to a moving background.

This script is based on Pauls idea, but gives you an additional option of adding the color you want, to the layer itself. It replaces all the colors with shades of black and fills in the alpha with the current foreground color. One thing his routine would Not do, was handle images that had any transparency in them if the color was added to the layer. However, I got it to work with transparency too, so if you have a brush or CG Text page, you can use this on it as well.


Original Image	Regular Colorize	New Colorize

You can go to the bottom of the page from here and click on the link to download this script, or follow along now as we break down the script, to show you how it does what it does. The acutal script is between the start and end George script lines. My comments will look like this < --- Comment Goes Here --- > and are not actually part of the script itself.

< ---------------------------------- Start of George Script ----------------------- >
// Colorize FX
// By J.L. White
// (C)2000 Visual Inspirations Inc.
// Based on idea by Paul Pichette
< --- The first lines are just comment lines. Anything that starts with // is a comment --- >

Param none
connect Aura Commands
< --- Tells Aura what options to use, like rectangle, circle, for this we need none --- >

tv_Request "Add Current Foreground Color To Layer Or Leave Transparent?| Add Color | Transparent "
BType = result
< --- Fill in image with current color or leave transparent so the next layer shows through --- >

tv_LayerSelectInfo
parse result FirstFrame NumSelectedFrames
CurrentFrame=FirstFrame
< --- Get Starting Frame & Total number of Frames --- >

if NumSelectedFrames == 1
   tv_LayerGetImage
   CurrentFrame = result
end
< --- If just one frame, sets current frame to process --- >

tv_GetWidth
parse result MyWidth
< --- Get Image Width --- >

tv_GetHeight
parse result MyHeight
< --- Get Image Height --- >

tv_LockDisplay "Now Processing Images"
< --- Lock interface so it does not redraw everything. Speeds things up! --- >

for i = 0 to (NumSelectedFrames-1)
   tv_LayerImage CurrentFrame
   tv_LayerSelect CurrentFrame 1
    tv_BrushCut 0 0 MyWidth MyHeight < --- Copy Image To A Brush --- >
    tv_Filter ColorOp.dll 0 0 MyWidth MyHeight "0 0 0 255-((r+g+b)/3)*a/256"
   < --- Converts to various alpha levels of black --- >
    if BType == 1
       tv_SpareSwap
       tv_Clear
       tv_Fill 0 0 < --- Fills with selected color --- >
       tv_SpareSwap
       tv_SpareToBack < --- Mixes color with image --- >
       tv_SpareSwap
       tv_Clear
       tv_Handle 0 0
       tv_Dot 0 0 < --- Stamps original down so it can be processed --- >
       tv_Filter ColorOp.dll 0 0 MyWidth MyHeight "r g b 255-a"
       < --- Reverses Alpha so images with Transparencies will work --- >
       tv_SpareSwap
       tv_SpareSubDensity < --- Final mix for image and alpha --- >
    end
    CurrentFrame = CurrentFrame+1
end

tv_LayerImage FirstFrame < --- Resets to first frame --- >
tv_UnlockDisplay < --- Unlocks the display --- >

exit
< --- Exits the script --- >
< ---------------------------------- End of George Script ----------------------- >

Click Here to Download Colorize.zip

Well that does it for this one, till next time...

To contact Jeff White you can E-Mail him at jeff@vionline.com