Delete Frames George Script

(A George Script For Aura)

Written By J.L. White

I wrote this to use with Aura 2, but hopefully some of you can find a use for it in Aura 1. I am a beta tester for Aura and have been working with the newest creation from Newtek. Sorry no new info here, you'll just have to wait! But they have given out a little info on some of the new features. One is that you can have multiple projects loaded. Well I was taking all the projects I had created for AuraFX and wanted to build them into one large project, so what I was doing was loading in one project, copying all the frames, then pasting them down in a new layer in another project. The problem is when you create a new layer and paste a selection into it, it still has the one frame left there. This is true in version 1 & 2, but the difference, is that version 1 leaves the blank frame at the beginning and version 2 leaves it at the end. I had 30 layers to go through and delete 1 damn frame out of each layer, so I wrote this to do it for me. While I was at it, I thought it might be useful to delete more than one frame and also put in the option of which end to delete it from. This lets you do all that. It first asks if you want to just delete from the Current Layer or ALL layers, then if you want it at the start or the end, then how many frames. That's it! It will take over and do the rest.

You can go to the bottom of the page from here and click on the link to download this script, or follow along now as we break down the script, to show you how it does what it does. The acutal script is between the start and end George script lines. My comments will look like this < --- Comment Goes Here --- > and are not actually part of the script itself.

< ---------------------------------- Start of George Script ----------------------- >
// Delete Frames
// By J.L. White
// (C)2000 Visual Inspirations Inc.
< --- The first 3 lines are just comment lines. Anything that starts with // is a comment --- >

Param none
connect Aura Commands
< --- Tells Aura what options to use, like rectangle, circle, for this we need none --- >

tv_Request "Delete Frames From What Layers?| All Layers | Current Layer "
WNum = result
< --- Select Which Layer To Work On --- >

tv_Request "Select Which Frames To Delete!| Frames At Start | Frames At End "
SENum = result
< --- Select Which End to Delete Frames from --- >

tv_ReqNum 1 1 10000 "Enter Number Of Frames To Delete!"
TNum = result
if CMP(TNum,"Cancel") == 1
   tv_Warn "Delete Frames Aborted!"
   exit
end
< --- Enter Number of Frames To Delete or Exit if "Cancel" is hit --- >

if WNum == 1 < --- Loop for ALL Layers --- >
    i=0
    do
       tv_LayerGetID i < --- Get ID and go one layer at a time --- >
       i = i+1
       MyID(i) = result
       tv_LayerSet MyID(i)
       tv_LayerCurrentID
       parse result FirstLayer
       tv_LayerInfo FirstLayer
       parse result LayerDisplay LayerPosition LayerDensity LayerName LayerType LayerStartFrame LayerEndFrame LayerTable
       if SENum == 1
          tv_LayerSelect LayerStartFrame TNum < --- Select Frames At Start --- >
       else
          tv_LayerSelect (LayerEndFrame-TNum)+1 TNum < --- Select Frames At End --- >
       end
       tv_LayerCut < --- Cut Selected Frames --- >
    Until (CMP(MyID(i),"none") == 1)

else < --- Routine for Current Layer --- >
    tv_LayerCurrentID
    parse result FirstLayer
    tv_LayerInfo FirstLayer
    parse result LayerDisplay LayerPosition LayerDensity LayerName LayerType LayerStartFrame LayerEndFrame LayerTable
    if SENum == 1
       tv_LayerSelect LayerStartFrame TNum < --- Select Frames At Start --- >
    else
       tv_LayerSelect (LayerEndFrame-TNum)+1 TNum < --- Select Frames At End --- >
    end
    tv_LayerCut < --- Cut Selected Frames --- >

end

exit
< --- Exit the script --- >
< ---------------------------------- End of George Script ----------------------- >

Click Here to Download DelFrames.zip

Well that does it for this one, till next time...

To contact Jeff White you can E-Mail him at jeff@vionline.com