Loop Layer George Script

(A George Script For Aura)

Written By J.L. White

Loop layer is designed to take an anim layer and loop it. This came about when Don & Ralph at Newtek asked me of a short cut for the demos they were doing. They were using some of the Digital Juice image sequences and loading them into Aura. These files were set to be played in a loop, but what about when you have other elements in your project. Say for example, you loaded in a 30 frame loop background but you have a 120 frame text animation layer. If you just stretched out the background layer , it would change the speed and quality of the original loop. So what you would need to do is this. Select the layer, hightlight all the frames, select Copy, then select the last frame, then do a Paste, then another paste, then yet another paste so your background would match your text anim.

With LoopLayer, all you do is click on the george script, enter 3 for the number of loops to add and your done.

You can go to the bottom of the page from here and click on the link to download this script, or follow along now as we break down the script, to show you how it does what it does. The acutal script is between the start and end George script lines. My comments will look like this < --- Comment Goes Here --- > and are not actually part of the script itself.

< ---------------------------------- Start of George Script ----------------------- >
// Loop Layer
// By J.L. White
// (C)2000 Visual Inspirations Inc.
< --- The first lines are just comment lines. Anything that starts with // is a comment --- >

Param none
connect Aura Commands
< --- Tells Aura what options to use, like rectangle, circle, for this we need none --- >

tv_ReqNum 1 1 1000 "Enter Number Of Loops To Add!"
Loops = result
if CMP(Loops,"Cancel") == 1
   tv_Warn "Loop Layer Aborted!"
   exit
end
< --- Ask user for number of loops to add --- >

tv_LayerCurrentID
parse result FirstLayer
< --- Find info on current layer and call it "FirstLayer" --- >

tv_LayerInfo FirstLayer
parse result LayerDisplay LayerPosition LayerDensity LayerName LayerType LayerStartFrame LayerEndFrame LayerTable
< --- Get infomation on "First Layer" --- >

CheckAnim = CMP(LayerType,"IMAGE")
if (CheckAnim == 1)
   tv_Warn "This Script Only Works On Anim Layers!"
   exit
end
< --- Make sure the layer is an anim layer --- >

NumSelectedFrames = (LayerEndFrame+1)
< --- Calculate Total number of frames --- >

tv_LayerImage 0
< --- Set current image to the 1st image in layer --- >

tv_LayerSelect 0 NumSelectedFrames
< --- Select all frames in layer --- >

tv_LayerCopy
< --- Copy the selected frames --- >

for i = 0 to Loops
   tv_LayerImage i*(NumSelectedFrames)
   tv_LayerPaste
end
< --- Paste the selected frames by the number of loops--- >

tv_LayerImage 0
< --- Reselect the first frame --- >

exit
< --- Exit the script --- >

< ---------------------------------- End of George Script ----------------------- >

Click Here to Download LoopLayer.zip

Well that does it for this one, till next time...

To contact Jeff White you can E-Mail him at jeff@vionline.com