Palette George Script

(A George Script For Aura)

Written By Ray Foster

(Note: Remember to edit the tv_savebrush & tv_loadpalette lines below,
to tell where to save your palette files before you begin)

You can go to the bottom of the page from here and click on the link to download this script, or take a look at the acutal script, which is between the start and end George script lines.

< ---------------------------------- Start of George Script ----------------------- >
// palette.grg - rfoster
// This script makes a 16 colour palette and that can be saved and
// reloaded by name. Palette directory needs to exist.
// Edit the highlighted lines below to give the full path to
// your palette directory.
// Once you start you need to make all 16 selections even if you
// don't require a 16 colour palette.

param none
connect "aura commands"

tv_request " Select 16 colours to make your new palette. |Continue|Stop"

ans=result
if ans==0
exit
end

tv_reqstring "Enter palette identifier"
parse result identifier
a=cmp(identifier,"cancel")
if a==1
exit
end

tv_layercurrentid
parse result layer1

tv_layercreate "palette"
tv_layercurrentid
parse result layer2

x1=0
y1=0
x2=4
y2=4

while iteration<16
tv_layerset layer1
tv_piccolor
parse result pen red green blue alpha

tv_setapen red green blue
tv_layerset layer2
tv_rectfill x1 y1 x2 y2

x1=x1
x2=x2
y1=y1+4
y2=y2+4

if y1>14
y1=0
x1=x1+4
x2=x2+4
y2=4
end

iteration=iteration+1
end

tv_brushcut 0 0 16 16 //visible palette
// 0 0 16 64 for full palette

tv_savemode deep
oldmode = result
/////////////////////////////////////////////
tv_savebrush "d:\palettes\palette."identifier
/////////////////////////////////////////////
tv_savemode oldmode
tv_layerset layer1
tv_layerkill layer2
//////////////////////////////////////////////
tv_loadpalette "d:\palettes\palette."identifier
//////////////////////////////////////////////
tv_selectshapetool
tv_inkpen

< ---------------------------------- End of George Script ----------------------- >

Click Here to Download Palette.zip

Well that does it for this one, till next time...

To contact Ray Foster you can E-Mail him at rfoster@idirect.com